main.qml Example File | Qt Quick Controls 5.5

- Qt 5.5
- Qt Quick Controls
- Qt Quick Controls - File System Browser Example
- main.qml Example File
- Qt 5.5.1 Reference Documentation

# main.qml Example File

filesystembrowser/main.qml

    /****************************************************************************
    **
    ** Copyright (C) 2015 The Qt Company Ltd.
    ** Contact: http://www.qt.io/licensing/
    **
    ** This file is part of the examples of the Qt Toolkit.
    **
    ** $QT_BEGIN_LICENSE:BSD$
    ** You may use this file under the terms of the BSD license as follows:
    **
    ** "Redistribution and use in source and binary forms, with or without
    ** modification, are permitted provided that the following conditions are
    ** met:
    **   * Redistributions of source code must retain the above copyright
    **     notice, this list of conditions and the following disclaimer.
    **   * Redistributions in binary form must reproduce the above copyright
    **     notice, this list of conditions and the following disclaimer in
    **     the documentation and/or other materials provided with the
    **     distribution.
    **   * Neither the name of The Qt Company Ltd nor the names of its
    **     contributors may be used to endorse or promote products derived
    **     from this software without specific prior written permission.
    **
    **
    ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
    ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
    ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
    ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
    ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
    ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
    ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
    ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
    ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
    ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
    ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
    **
    ** $QT_END_LICENSE$
    **
    ****************************************************************************/

    import QtQuick 2.2
    import QtQuick.Controls 1.4
    import QtQml.Models 2.2

    ApplicationWindow {
        visible: true
        width: 640
        height: 480
        title: qsTr("File System")

        menuBar: MenuBar {
            Menu {
                title: qsTr("File")
                MenuItem {
                    text: qsTr("Exit")
                    onTriggered: Qt.quit();
                }
            }
        }

        Row {
            id: row
            anchors.top: parent.top
            anchors.topMargin: 12
            anchors.horizontalCenter: parent.horizontalCenter

            ExclusiveGroup {
                id: eg
            }

            Repeater {
                model: [ "None", "Single", "Extended", "Multi", "Contig."]
                Button {
                    text: modelData
                    exclusiveGroup: eg
                    checkable: true
                    checked: index === 1
                    onClicked: view.selectionMode = index
                }
            }
        }

        ItemSelectionModel {
            id: sel
            model: fileSystemModel
        }

        TreeView {
            id: view
            anchors.fill: parent
            anchors.margins: 2 * 12 + row.height
            model: fileSystemModel
            selection: sel

            TableViewColumn {
                title: "Name"
                role: "fileName"
                resizable: true
            }

            TableViewColumn {
                title: "Size"
                role: "size"
                resizable: true
                horizontalAlignment : Text.AlignRight
            }

            TableViewColumn {
                title: "Permissions"
                role: "displayableFilePermissions"
                resizable: true
            }

            TableViewColumn {
                title: "Date Modified"
                role: "lastModified"
                resizable: true
            }

            onDoubleClicked: isExpanded(index) ? collapse(index) : expand(index)
            onActivated : Qt.openUrlExternally(fileSystemModel.data(index, 263))
        }
    }